User Tools

Site Tools


userspace:adobe_reader_x

This is an old revision of the document!


Adobe Reader X

Tested with opsi 4.0.1 Tested with opsi-winst 4.10.x - 4.11.1.6 Tested with Windows XP Professional and Windows 7 Enterprise x64

Installation Script for Adobe Reader X with some Program Settings changed in Registry Deinstallation Script for Adobe Reader Versions 9.3.1 - 10.1.1

Install.ins

[Initial]



;Standard Text, der während der Installation angezeigt wird

	Message = Bitte warten, das Produkt wird installiert







;Loglevel einstellen

	setLogLevel = 6







;Bei Fehlern abbrechen

	ExitOnError=false







;Syntax Fehler werden in einem separaten Fenster angezeigt

	ScriptErrorMessages=on







;Single-Step Mode nicht verwenden

	TraceMode=off







;Im Batchmode das Winst-Fenster nicht im Vordergrund anzeigen

	StayOnTop=false











[Actions]



;Variable für die Ermittlung des Betriebssystems

	DefVar $OS$

		set $OS$ = GetOS







;Variable für die Ermittlung der Betriebssystem Unterversion

	DefVar $NTVersion$

		set $NTVersion$ = GetNTVersion







;Name des Produkts (max. 12 Zeichen)

	DefVar $ProductName$

		Set $ProductName$ = "Adobe Reader"







;Dateiname des Produktbildes mit Erweiterung

	DefVar $ProductPicture$

		Set $ProductPicture$ = "AdobeReader.png"







;Die Variable zur Auswertung des ExitCodes

	DefVar $ExitCode$







;Vollständiger Produktname incl. Versionsnummer

	DefVar $ProductNameFull1$

		set $ProductNameFull1$ = "Adobe Reader X 10.1.0"



	DefVar $ProductNameFull2$

		set $ProductNameFull2$ = "Adobe Reader X 10.1.1"







;Dateinamen der zu installierenden MSI-Pakete

	DefVar $Executable1$

		Set $Executable1$ = "AdbeRdr1010_de_DE.msi"



	DefVar $Executable2$

		Set $Executable2$ = "AdbeRdrUpd1011.msp"







;Prüfen der Winst Version

	requiredWinstVersion >= "4.11"







;Anzeigen der Installationsbenachrichtigung incl. des vollen Produktnamens

	Message "Installiere "+$ProductNameFull1$







;$ProductPicture$ und $ProductName$ anzeigen

	ShowBitmap /3 "%scriptpath%\" + $ProductPicture$ $ProductName$







;Freien Speicherplatz ermitteln

	if not (HasMinimumSpace ("%SYSTEMDRIVE%", "500 MB"))

		LogError "Nicht genügend Platz auf %SYSTEMDRIVE%"

			isFatalError

	endif







;OS-Version ermitteln

	if ( $NTVersion$ = "Win2K" OR $NTVersion$ = "WinXP" OR $NTVersion$ = "Win NT 5.2" OR $NTVersion$ = "Windows Vista" )







		Winbatch_Install_Reader

			sub "%ScriptDrive%\install\check_exitcode\check_msi-exitcode.ins"



		Message "Installiere "+$ProductNameFull2$

			Winbatch_Install_Update1

				sub "%ScriptDrive%\install\check_exitcode\check_msi-exitcode.ins"



		LinkFolder_Custom

		Registry_Global /32Bit

		Registry_User /SysNative /AllNTUserdats







	else

		LogError "Kein kompatibles Betriebssystem installiert"

			isFatalError

	endif











[Winbatch_Install_Reader]



	msiexec.exe /i "%SCRIPTPATH%\$Executable1$" /qb-! /norestart ALLUSERS=1 EULA_ACCEPT=YES SUPPRESS_APP_LAUNCH=YES







[Winbatch_Install_Update1]



	msiexec.exe /p "%SCRIPTPATH%\$Executable2$" /qb-!







[LinkFolder_Custom]



;Desktop Verknüpfung löschen

	set_basefolder common_desktopdirectory

		set_subfolder ""

			delete_element "Adobe Reader X"







;Startmenü anpassen

	set_basefolder common_programs

		set_subfolder ""

			delete_element "$ProductName$"

				set_subfolder ""

					set_link

						name: $ProductName$

						target: "%ProgramFiles32Dir%\Adobe\Reader 10.0\Reader\AcroRd32.exe"

						parameters:

						working_dir: "%ProgramFiles32Dir%\Adobe\Reader 10.0\"

						icon_file:

						icon_index:

					end_link







[Registry_Global]



;Deaktiviert Adobe Updater

	OpenKey [HKLM\SOFTWARE\Adobe\Adobe ARM\1.0\ARM]

		Set "iCheck"=REG_DWORD:0x00000000



;Verhindert automatisches Laden von Reader_sl.exe beim Rechnerstart

	OpenKey [HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run]

		DeleteVar "Adobe Reader Speed Launcher"

		DeleteVar "Adobe ARM"







[Registry_User]



;Mitteilungen beim Starten von Reader anzeigen deaktivieren

	OpenKey [Software\Adobe\Acrobat Reader\10.0\IPM]

		Set "bShowMsgAtLaunch"=REG_DWORD:0x00000000







;Eröffnungsbildschirm anzeigen deaktivieren

	OpenKey [Software\Adobe\Acrobat Reader\10.0\Originals]

		Set "bDisplayAboutDialog"=REG_DWORD:0x00000000







;Nur zertifizierte Zusatzmodule verwenden aktivieren

	OpenKey [Software\Adobe\Acrobat Reader\10.0\Originals]

		Set "iTrustedMode"=REG_DWORD:0x00000001







;Verbindungsgeschwindigkeit auf LAN einstellen

	OpenKey [Software\Adobe\Acrobat Reader\10.0\AVGeneral]

		Set "iConnectionSpeed"=REG_DWORD:0x00989680







;JavaScript deaktivieren

	OpenKey [Software\Adobe\Acrobat Reader\10.0\JSPrefs]

		Set "bEnableJS" = REG_DWORD:0x00000000

Uninstall.ins

[Initial]



;Standard Text, der während der Deinstallation angezeigt wird

	Message = Bitte warten, das Produkt wird deinstalliert







;Loglevel einstellen

	setLogLevel = 6







;Bei Fehlern abbrechen

	ExitOnError = false







;Syntax Fehler werden in einem separaten Fenster angezeigt

	ScriptErrorMessages = on







;Single-Step Mode nicht verwenden

	TraceMode = off







;Im Batchmode das Winst-Fenster nicht im Vordergrund anzeigen

	StayOnTop = false











[Actions]



;Name des Produkts (max. 12 Zeichen)

	DefVar $ProductName$

		Set $ProductName$ = "Adobe Reader"







;Dateiname des Produktbildes mit Erweiterung

	DefVar $ProductPicture$

		Set $ProductPicture$ = "AdobeReader.png"







;Die Variable zur Auswertung des ExitCodes

	DefVar $ExitCode$







;$ProductPicture$ und $ProductName$ anzeigen

	ShowBitmap /3 "%scriptpath%\" + $ProductPicture$ $ProductName$











sub "%ScriptPath%\SubUninstall.ins"

SubUninstall.ins

;Variable für den msiexec Aufruf zur Deinstallation
	DefVar $UninstallCommand$



;Variable für die jeweilige Version. Wird aus der Registry ausgelesen
	DefVar $DisplayName$





;Adobe Reader 9.3.1 - 9.3.4 deinstallieren, wenn es in der Registry gefunden wurde
	Set $DisplayName$ = GetRegistrystringvalue32("[HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{AC76BA86-7AD7-1031-7B44-A93000000001}] DisplayName")
		if not ($DisplayName$ = "")

			Message "Deinstalliere "+$DisplayName$
				set $UninstallCommand$ = "MsiExec.exe /x {AC76BA86-7AD7-1031-7B44-A93000000001} /qb-! REBOOT=ReallySuppress"
					Winbatch_Uninstall
						sub "%ScriptDrive%\install\check_exitcode\check_msi-exitcode.ins"

		endif





;Adobe Reader 9.4.0 deinstallieren, wenn es in der Registry gefunden wurde
	Set $DisplayName$ = GetRegistrystringvalue32("[HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{AC76BA86-7AD7-1031-7B44-A94000000001}] DisplayName")
		if not ($DisplayName$ = "")

			Message "Deinstalliere "+$DisplayName$
				set $UninstallCommand$ = "MsiExec.exe /x {AC76BA86-7AD7-1031-7B44-A94000000001} /qb-! REBOOT=ReallySuppress"
					Winbatch_Uninstall
						sub "%ScriptDrive%\install\check_exitcode\check_msi-exitcode.ins"

		endif



;Adobe Reader 10.0.x deinstallieren, wenn es in der Registry gefunden wurde
	Set $DisplayName$ = GetRegistrystringvalue32("[HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{AC76BA86-7AD7-1031-7B44-AA0000000001}] DisplayName")
		if not ($DisplayName$ = "")

			Message "Deinstalliere "+$DisplayName$
				set $UninstallCommand$ = "MsiExec.exe /x {AC76BA86-7AD7-1031-7B44-AA0000000001} /qb-! REBOOT=ReallySuppress"
					Winbatch_Uninstall
						sub "%ScriptDrive%\install\check_exitcode\check_msi-exitcode.ins"

		endif



;Adobe Reader 10.1.x deinstallieren, wenn es in der Registry gefunden wurde
	Set $DisplayName$ = GetRegistrystringvalue32("[HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{AC76BA86-7AD7-1031-7B44-AA1000000001}] DisplayName")
		if not ($DisplayName$ = "")

			Message "Deinstalliere "+$DisplayName$
				set $UninstallCommand$ = "MsiExec.exe /x {AC76BA86-7AD7-1031-7B44-AA1000000001} /qb-! REBOOT=ReallySuppress"
					Winbatch_Uninstall
						sub "%ScriptDrive%\install\check_exitcode\check_msi-exitcode.ins"

		endif



Linkfolder_Custom





[Winbatch_Uninstall]

	$UninstallCommand$



[Linkfolder_Custom]

;Startmenü Verknüpfung löschen
	Set_basefolder common_programs
		Set_subfolder ""
			delete_element "$ProductName$"
userspace/adobe_reader_x.1317967521.txt.gz · Last modified: 2021/08/23 08:37 (external edit)