User Tools

Site Tools


userspace:adobe_reader_x

This is an old revision of the document!


Adobe Reader 10.1.1

Script by Der-Matze
Comments and improvements welcome

Tested with opsi 4.0.1
Tested with opsi-winst 4.10.x - 4.11.1.6
Tested with Windows XP Professional and Windows 7 Enterprise x64

Installation Script for Adobe Reader X with some Program Settings changed in Registry
Uninstallation Script for Adobe Reader Versions 9.3.1 - 10.1.1

This script uses the check_msi-exitcode script: https://forum.opsi.org/wiki/userspace:check_msi-exitcode

The installation files can be downloaded from: ftp://ftp.adobe.com/pub/adobe/reader/win/10.x/10.1.1/

Install.ins

;Standard Text, shown during installation
Message = Bitte warten, das Produkt wird installiert
;Set Loglevel
setLogLevel = 6
;Stop when errors
ExitOnError = false
;Syntax Error are shown in a seperate window
ScriptErrorMessages = on
;Do not use Single-Step Mode
TraceMode = off
;No winst-window in foreground while batchmode
StayOnTop = false
 
 
[Actions]
;Variable for the OS
DefVar $OS$
set $OS$ = GetOS
;Variable for the OS-subversion
DefVar $NTVersion$
set $NTVersion$ = GetNTVersion
 
;Name of product (max. 12 columns)
DefVar $ProductName$
Set $ProductName$ = "Adobe Reader"
 
;filename of productpicture with extension
DefVar $ProductPicture$
Set $ProductPicture$ = "AdobeReader.png"
 
;the variable for the ExitCode
DefVar $ExitCode$
 
 
;complete name of product incl. versionno.
DefVar $ProductNameFull1$
set $ProductNameFull1$ = "Adobe Reader X 10.1.0"
DefVar $ProductNameFull2$
set $ProductNameFull2$ = "Adobe Reader X 10.1.1"
 
;filename of MSI-package which has to be installed
DefVar $Executable1$
Set $Executable1$ = "AdbeRdr1010_de_DE.msi"
DefVar $Executable2$
Set $Executable2$ = "AdbeRdrUpd1011.msp"
 
;Check the winst-version
requiredWinstVersion >= "4.11"
 
;Show installation-message with full productname
Message "Installiere "+$ProductNameFull1$
 
;show $ProductPicture$ and $ProductName$
ShowBitmap /3 "%scriptpath%\" + $ProductPicture$ $ProductName$
 
;check free diskspace
if not (HasMinimumSpace ("%SYSTEMDRIVE%", "500 MB"))
	LogError "Nicht genügend Platz auf %SYSTEMDRIVE%"
	isFatalError
endif
 
;Get OS-Version
if ( $NTVersion$ = "Win2K" OR $NTVersion$ = "WinXP" OR $NTVersion$ = "Win NT 5.2" OR $NTVersion$ = "Windows Vista" )
	Winbatch_Install_Reader
	sub "%ScriptDrive%\install\check_exitcode\check_msi-exitcode.ins"
	Message "Installiere "+$ProductNameFull2$
	Winbatch_Install_Update1
	sub "%ScriptDrive%\install\check_exitcode\check_msi-exitcode.ins"
	LinkFolder_Custom
	Registry_Global /32Bit
	Registry_User /SysNative /AllNTUserdats
else
	LogError "Kein kompatibles Betriebssystem installiert"
	isFatalError
endif
 
[Winbatch_Install_Reader]
msiexec.exe /i "%SCRIPTPATH%\$Executable1$" /qb-! /norestart ALLUSERS=1 EULA_ACCEPT=YES SUPPRESS_APP_LAUNCH=YES
 
[Winbatch_Install_Update1]
msiexec.exe /p "%SCRIPTPATH%\$Executable2$" /qb-!
 
[LinkFolder_Custom]
;Delete Desktop-Link
set_basefolder common_desktopdirectory
set_subfolder ""
delete_element "Adobe Reader X"
 
;Configure Startmenu
set_basefolder common_programs
set_subfolder ""
delete_element "Adobe Reader X"
set_subfolder ""
set_link
name: $ProductName$
target: "%ProgramFiles32Dir%\Adobe\Reader 10.0\Reader\AcroRd32.exe"
parameters:
working_dir: "%ProgramFiles32Dir%\Adobe\Reader 10.0\"
icon_file:
icon_index:
end_link
 
[Registry_Global]
;Deactivate Adobe Updater
OpenKey [HKLM\SOFTWARE\Adobe\Adobe ARM\1.0\ARM]
Set "iCheck"=REG_DWORD:0x00000000
 
;Avoids start of Reader_sl.exe while booting
OpenKey [HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Run]
DeleteVar "Adobe Reader Speed Launcher"
DeleteVar "Adobe ARM"
 
[Registry_User]
;Avoids splash-screens during start of the reader
OpenKey [Software\Adobe\Acrobat Reader\10.0\IPM]
Set "bShowMsgAtLaunch"=REG_DWORD:0x00000000
 
;Avoid Splash-Screen
OpenKey [Software\Adobe\Acrobat Reader\10.0\Originals]
Set "bDisplayAboutDialog"=REG_DWORD:0x00000000
 
;Allow only certified Addons
OpenKey [Software\Adobe\Acrobat Reader\10.0\Originals]
Set "iTrustedMode"=REG_DWORD:0x00000001
 
;Set connection-speed to LAN
OpenKey [Software\Adobe\Acrobat Reader\10.0\AVGeneral]
Set "iConnectionSpeed"=REG_DWORD:0x00989680
 
;deactivate JavaScript
OpenKey [Software\Adobe\Acrobat Reader\10.0\JSPrefs]
Set "bEnableJS" = REG_DWORD:0x00000000

Uninstall.ins

;Standard Text, shown during installation
Message = Bitte warten, das Produkt wird deinstalliert
 
;Set Loglevel
setLogLevel = 6
 
;Stop when errors
ExitOnError = false
;Syntax Fehler are shown in a seperate window
ScriptErrorMessages = on
;Do not use Single-Step Mode
TraceMode = off
;No winst-window in foreground while batchmode
StayOnTop = false
 
[Actions]
;Name of product (max. 12 columns)
DefVar $ProductName$
Set $ProductName$ = "Adobe Reader"
 
;filename of productpicture with extension
DefVar $ProductPicture$
Set $ProductPicture$ = "AdobeReader.png"
 
;the variable for the ExitCode
DefVar $ExitCode$
 
;show $ProductPicture$ and $ProductName$
ShowBitmap /3 "%scriptpath%\" + $ProductPicture$ $ProductName$
 
sub "%ScriptPath%\SubUninstall.ins"

SubUninstall.ins

;Variable for msiexec-call of deinstallation
DefVar $UninstallCommand$
 
 
 
;Variable for the diffrent versions gotten from the registry
DefVar $DisplayName$
 
;Deinstalling Adobe Reader 9.3.1 - 9.3.4, if found in the Registry
Set $DisplayName$ = GetRegistrystringvalue32("[HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{AC76BA86-7AD7-1031-7B44-A93000000001}] DisplayName")
if not ($DisplayName$ = "")
	Message "Deinstalliere "+$DisplayName$
	set $UninstallCommand$ = "MsiExec.exe /x {AC76BA86-7AD7-1031-7B44-A93000000001} /qb-! REBOOT=ReallySuppress"
	Winbatch_Uninstall
	sub "%ScriptDrive%\install\check_exitcode\check_msi-exitcode.ins"
endif
 
;Deinstalling Adobe Reader 9.4.0, if found in the Registry
Set $DisplayName$ = GetRegistrystringvalue32("[HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{AC76BA86-7AD7-1031-7B44-A94000000001}] DisplayName")
if not ($DisplayName$ = "")
	Message "Deinstalliere "+$DisplayName$
	set $UninstallCommand$ = "MsiExec.exe /x {AC76BA86-7AD7-1031-7B44-A94000000001} /qb-! REBOOT=ReallySuppress"
	Winbatch_Uninstall
	sub "%ScriptDrive%\install\check_exitcode\check_msi-exitcode.ins"
endif
 
;Deinstalling Adobe Reader 10.0.x, if found in the Registry
Set $DisplayName$ = GetRegistrystringvalue32("[HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{AC76BA86-7AD7-1031-7B44-AA0000000001}] DisplayName")
if not ($DisplayName$ = "")
	Message "Deinstalliere "+$DisplayName$
	set $UninstallCommand$ = "MsiExec.exe /x {AC76BA86-7AD7-1031-7B44-AA0000000001} /qb-! REBOOT=ReallySuppress"
	Winbatch_Uninstall
	sub "%ScriptDrive%\install\check_exitcode\check_msi-exitcode.ins"
endif
 
;Deinstalling Adobe Reader 10.1.x, if found in the Registry
Set $DisplayName$ = GetRegistrystringvalue32("[HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{AC76BA86-7AD7-1031-7B44-AA1000000001}] DisplayName")
	if not ($DisplayName$ = "")
	Message "Deinstalliere "+$DisplayName$
	set $UninstallCommand$ = "MsiExec.exe /x {AC76BA86-7AD7-1031-7B44-AA1000000001} /qb-! REBOOT=ReallySuppress"
	Winbatch_Uninstall
	sub "%ScriptDrive%\install\check_exitcode\check_msi-exitcode.ins"
endif
 
Linkfolder_Custom
 
[Winbatch_Uninstall]
$UninstallCommand$
 
[Linkfolder_Custom]
;Delete Startmenu-Link
Set_basefolder common_programs
Set_subfolder ""
delete_element "$ProductName$"
userspace/adobe_reader_x.1389259034.txt.gz · Last modified: 2021/08/23 08:37 (external edit)